indows產(chǎn)品密鑰是很重要的一個密碼，它是我們重新安裝激活操作系統(tǒng)時必須要使用的，如果丟失或忘記了Windows產(chǎn)品密鑰，將給我們帶來很大的麻煩。
下面我將提供一個解決方案，你將看到如何使用簡單的VBS腳本來顯示已安裝的Windows 10、Windows 8或Windows 7系統(tǒng)的產(chǎn)品密鑰。這是從電腦上安裝的操作系統(tǒng)中提取產(chǎn)品密鑰的一個非常簡單的解決方案，無需使用任何第三方軟件。
與其它方法相比，這個VBScript解決方案幾乎是完美的，用戶只需要單擊文件即可。
要查看電腦上安裝的Windows 10產(chǎn)品密鑰，請執(zhí)行以下操作：
1.打開記事本。
2.將以下文本復制并粘貼到“記事本”窗口中：
Option Explicit
Dim objshell,path,DigitalID, Result
Set objshell = CreateObject("WScript.Shell")
'Set registry key path
Path = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\"
'Registry key value
DigitalID = objshell.RegRead(Path & "DigitalProductId")
Dim ProductName,ProductID,ProductKey,ProductData
'Get ProductName, ProductID, ProductKey
ProductName = "Product Name: " & objshell.RegRead(Path & "ProductName")
ProductID = "Product ID: " & objshell.RegRead(Path & "ProductID")
ProductKey = "Installed Key: " & ConvertToKey(DigitalID)
ProductData = ProductName & vbNewLine & ProductID & vbNewLine & ProductKey
'Show messbox if save to a file
If vbYes = MsgBox(ProductData & vblf & vblf & "Save to a file?", vbYesNo + vbQuestion, "BackUp Windows Key Information") then
Save ProductData
End If
'Convert binary to chars
Function ConvertToKey(Key)
Const KeyOffset = 52
Dim isWin8, Maps, i, j, Current, KeyOutput, Last, keypart1, insert
'Check if OS is Windows 8
isWin8 = (Key(66) \ 6) And 1
Key(66) = (Key(66) And &HF7) Or ((isWin8 And 2) * 4)
i = 24
Maps = "BCDFGHJKMPQRTVWXY2346789"
Do
Current= 0
j = 14
Do
Current = Current* 256
Current = Key(j + KeyOffset) + Current
Key(j + KeyOffset) = (Current \ 24)
Current=Current Mod 24
j = j -1
Loop While j >= 0
i = i -1
KeyOutput = Mid(Maps,Current+ 1, 1) & KeyOutput
Last = Current
Loop While i >= 0
If (isWin8 = 1) Then
keypart1 = Mid(KeyOutput, 2, Last)
insert = "N"
KeyOutput = Replace(KeyOutput, keypart1, keypart1 & insert, 2, 1, 0)
If Last = 0 Then KeyOutput = insert & KeyOutput
End If
ConvertToKey = Mid(KeyOutput, 1, 5) & "-" & Mid(KeyOutput, 6, 5) & "-" & Mid(KeyOutput, 11, 5) & "-" & Mid(KeyOutput, 16, 5) & "-" & Mid(KeyOutput, 21, 5)
End Function
'Save data to a file
Function Save(Data)
Dim fso, fName, txt,objshell,UserName
Set objshell = CreateObject("wscript.shell")
'Get current user name
UserName = objshell.ExpandEnvironmentStrings("%UserName%")
'Create a text file on desktop
fName = "C:\Users\" & UserName & "\Desktop\WindowsKeyInfo.txt"
Set fso = CreateObject("Scripting.FileSystemObject")
Set txt = fso.CreateTextFile(fName)
txt.Writeline Data
txt.Close
End Function 3.單擊“文件－另存為”命令，在“保存類型”中選擇“所有文件”，在“文件名”中將上面的文本保存到桌面上帶有“ .vbs”擴展名的文件中，文件名可以自己隨意命名。
提示：為確保正確保存擴展名為“ .vbs”的文件，可以鍵入文件名并用雙引號引起來，例如“BackupWindowsKey.vbs”。
現(xiàn)在打開BackupWindowsKey.vbs文件,瞧，Windows10產(chǎn)品密鑰會顯示在屏幕上！把它記錄下來，保存到一個安全的地方。
如果你想直接下載得到BackupWindowsKey.vbs文件，請關(guān)注我，然后私信“密鑰腳本”。
我在Windows 7、Windows 8和Windows 10上測試了該技巧，它在所有提到的操作系統(tǒng)中均能完美運行。
■＞＞恢復win10登錄密碼的9大工具，一個比一個強大，維修電腦必備
■＞＞在Windows 10中管理用戶帳戶和密碼
■＞＞如何重置忘記的Windows10密碼，掌握這3個技巧就行了
■＞＞永久刪除桌面上激活Windows10水印，電腦高手都在用的技巧
更多windows 10操作系統(tǒng)使用技巧，請關(guān)注→→#win10玩機技巧#
想了解更多精彩內(nèi)容，快來關(guān)注@微課傳媒
1.頭條號【微課傳媒】專注軟件分享，如果你喜歡玩軟件，歡迎關(guān)注、評論、收藏、轉(zhuǎn)發(fā)。
2.在學習中有什么問題，歡迎與我溝通交流，號搜索【微課傳媒】，我在這里等你喲！
電腦系統(tǒng)win10密鑰怎么查看？在如今，越多的用戶選擇使用win10系統(tǒng)，但是小伙伴們知道嗎，在使用win10系統(tǒng)之前需要先使用密鑰激活，這樣才可以使用全部功能，那怎么查看自己的密鑰呢？
在Windows10桌面上找到【此電腦】，使用鼠標右擊選擇查看【屬性】，或者直接通過【win】鍵打開開始菜單選擇【系統(tǒng)】，打開系統(tǒng)界面后滑動點擊最下方的【W(wǎng)indows激活】查看到當前系統(tǒng)使用的產(chǎn)品密鑰。
使用【win+R】快捷鍵打開運行窗口，在輸入框中輸入命令【regedit】點擊確定打開注冊表編輯器，打開文件夾定位到【HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\SoftwareProtectionPlatform】，可直接復制路徑在地址欄粘貼快速打開。
打開所在路徑后，在右側(cè)找到【BackupProductKeyDefault】名稱一行，雙擊名稱打開編輯字符串窗口，通過【數(shù)值數(shù)據(jù)】即可找到當前Windows10系統(tǒng)的產(chǎn)品密鑰。
以上就是Windows10電腦產(chǎn)品密鑰在哪里可以查看全部內(nèi)容了，希望以上內(nèi)容對您有所幫助！喜歡文章就關(guān)注【源代碼設(shè)計筆記】，小編后期會不定期地更新科技資訊。