Windows產品密鑰是很重要的一個密碼，它是我們重新安裝激活操作系統時必須要使用的，如果丟失或忘記了Windows產品密鑰，將給我們帶來很大的麻煩。

下面我將提供一個解決方案，你將看到如何使用簡單的VBS腳本來顯示已安裝的Windows 10、Windows 8或Windows 7系統的產品密鑰。這是從電腦上安裝的操作系統中提取產品密鑰的一個非常簡單的解決方案，無需使用任何第三方軟件。

與其它方法相比，這個VBScript解決方案幾乎是完美的，用戶只需要單擊文件即可。

一、創建腳本文件

要查看電腦上安裝的Windows 10產品密鑰，請執行以下操作：

1.打開記事本。

2.將以下文本復制并粘貼到“記事本”窗口中：

Option Explicit  
 
Dim objshell,path,DigitalID, Result  
Set objshell = CreateObject("WScript.Shell") 
'Set registry key path 
Path = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\" 
'Registry key value 
DigitalID = objshell.RegRead(Path & "DigitalProductId") 
Dim ProductName,ProductID,ProductKey,ProductData 
'Get ProductName, ProductID, ProductKey 
ProductName = "Product Name: " & objshell.RegRead(Path & "ProductName") 
ProductID = "Product ID: " & objshell.RegRead(Path & "ProductID") 
ProductKey = "Installed Key: " & ConvertToKey(DigitalID)  
ProductData = ProductName  & vbNewLine & ProductID  & vbNewLine & ProductKey 
'Show messbox if save to a file  
If vbYes = MsgBox(ProductData  & vblf & vblf & "Save to a file?", vbYesNo + vbQuestion, "BackUp Windows Key Information") then 
   Save ProductData  
End If 
 
 
 
'Convert binary to chars 
Function ConvertToKey(Key) 
    Const KeyOffset = 52 
    Dim isWin8, Maps, i, j, Current, KeyOutput, Last, keypart1, insert 
    'Check if OS is Windows 8 
    isWin8 = (Key(66) \ 6) And 1 
    Key(66) = (Key(66) And &HF7) Or ((isWin8 And 2) * 4) 
    i = 24 
    Maps = "BCDFGHJKMPQRTVWXY2346789" 
    Do 
           Current= 0 
        j = 14 
        Do 
           Current = Current* 256 
           Current = Key(j + KeyOffset) + Current 
           Key(j + KeyOffset) = (Current \ 24) 
           Current=Current Mod 24 
            j = j -1 
        Loop While j >= 0 
        i = i -1 
        KeyOutput = Mid(Maps,Current+ 1, 1) & KeyOutput 
        Last = Current 
    Loop While i >= 0  
     
    If (isWin8 = 1) Then 
        keypart1 = Mid(KeyOutput, 2, Last) 
        insert = "N" 
        KeyOutput = Replace(KeyOutput, keypart1, keypart1 & insert, 2, 1, 0) 
        If Last = 0 Then KeyOutput = insert & KeyOutput 
    End If     
     
 
    ConvertToKey = Mid(KeyOutput, 1, 5) & "-" & Mid(KeyOutput, 6, 5) & "-" & Mid(KeyOutput, 11, 5) & "-" & Mid(KeyOutput, 16, 5) & "-" & Mid(KeyOutput, 21, 5) 
    
     
End Function 
'Save data to a file 
Function Save(Data) 
    Dim fso, fName, txt,objshell,UserName 
    Set objshell = CreateObject("wscript.shell") 
    'Get current user name  
    UserName = objshell.ExpandEnvironmentStrings("%UserName%")  
    'Create a text file on desktop  
    fName = "C:\Users\" & UserName & "\Desktop\WindowsKeyInfo.txt" 
    Set fso = CreateObject("Scripting.FileSystemObject") 
    Set txt = fso.CreateTextFile(fName) 
    txt.Writeline Data 
    txt.Close 
End Function 

3.單擊“文件－另存為”命令，在“保存類型”中選擇“所有文件”，在“文件名”中將上面的文本保存到桌面上帶有“ .vbs”擴展名的文件中，文件名可以自己隨意命名。

提示：為確保正確保存擴展名為“ .vbs”的文件，可以鍵入文件名并用雙引號引起來，例如“BackupWindowsKey.vbs”。

二、查看/備份Windows10產品密鑰

現在打開BackupWindowsKey.vbs文件,瞧，Windows10產品密鑰會顯示在屏幕上！把它記錄下來，保存到一個安全的地方。

如果你想直接下載得到BackupWindowsKey.vbs文件，請關注我，然后私信“密鑰腳本”。

我在Windows 7、Windows 8和Windows 10上測試了該技巧，它在所有提到的操作系統中均能完美運行。

擴展閱讀：

■＞＞恢復win10登錄密碼的9大工具，一個比一個強大，維修電腦必備

■＞＞在Windows 10中管理用戶帳戶和密碼

■＞＞如何重置忘記的Windows10密碼，掌握這3個技巧就行了

■＞＞永久刪除桌面上激活Windows10水印，電腦高手都在用的技巧

更多windows 10操作系統使用技巧，請關注→→#win10玩機技巧#

想了解更多精彩內容，快來關注@微課傳媒

1.頭條號【微課傳媒】專注軟件分享，如果你喜歡玩軟件，歡迎關注、評論、收藏、轉發。

2.在學習中有什么問題，歡迎與我溝通交流，號搜索【微課傳媒】，我在這里等你喲！

有許多網友最近詢問了如何查看Win10專業機器的激活碼。安裝Win10的第一件事是激活系統。否則，大多數功能都無法使用。如果我用軟件激活它，激活碼是什么？有沒有辦法找到它？本文教程和每個人都討論了特定的視圖方法。

腳步：

1，“win + r”打開運行窗口，在窗口中的文本框中輸入命令regedit，然后單擊“確定”按鈕打開注冊表編輯器窗口。

2，在Open Registry Editor窗口中定位HKEY_LOCAL_MACHINE / CurrentVersion / SoftwareProtectionPlorm注冊表項。

3，然后在右側找到窗口中的BackupProductKeyDefault注冊表項值。

4.雙擊“打開BackupProductKeyDefault注冊表”鍵值，您可以在編輯窗口中看到系統激活密鑰。

以上是Win10激活碼正在閱讀詳細介紹的地方，我希望幫助每個人。